@rest定义 不限数量 的输入

@optional 定义 可有可无 的输入，需要按顺序

@key 定义 可有可无 的输入，需要指定参数名

注意 ：语法上 @optional 和 @key 不能同时使用，功能上 @rest 和 @optional 同时使用会存在矛盾。

@rest用法例子：

procedure( myAdd( @rest args ) ; 修饰符号写在被修饰参数的前面

  prog(( result )

    result = 0

    foreach( num args

      printf( "myAdd: %n + %n\n" result num )

      result += num

    )

    return( result )

  )

); myAdd

运行结果：

myAdd( 1 2 3 )

; myAdd: 0 + 1

; myAdd: 1 + 2

; myAdd: 3 + 3

; => 6

@optional用法例子：

procedure( myCalc( args @optional opt("+") )  ; 参数后面的括号内写上默认值，也可以写成 ( opt "+" )

  prog(( result )

    result = car( args )

    args   = cdr( args )

    foreach( num args

      printf( "myCalc: %n %s %n ; " result opt num )

      case(opt

        ("+"  result += num )

        ("-"  result -= num )

        ("*"  result *= num )

        ("/"  result /= num )

      ); 按照不同的 opt 执行不同的操作

    )

    return( result )

  )

); myCalc

运行结果：

myCalc( list( 1 2 3 ))

; myCalc: 1 + 2 ; myCalc: 3 + 3 ; 

; => 6

myCalc( list( 1 2 3 ) "-")

; myCalc: 1 - 2 ; myCalc: -1 - 3 ; 

; => -4

myCalc( list( 1 2 3 ) "*")

; myCalc: 1 * 2 ; myCalc: 2 * 3 ; 

; => 6

myCalc( list( 1.0 2 3 ) "/")

; myCalc: 1.000000 / 2 ; myCalc: 0.500000 / 3 ; 

; => 0.1666667

@key用法例子：

procedure( myCalc( @key args opt("+") )

  prog(( result )

    result = car( args )

    args   = cdr( args )

    foreach( num args

      printf( "myCalc: %n %s %n ; " result opt num )

      case(opt

        ("+"  result += num )

        ("-"  result -= num )

        ("*"  result *= num )

        ("/"  result /= num )

      ); 按照不同的 opt 执行不同的操作

    )

    return( result )

  )

); myCalc

运行结果：

myCalc( ?opt "+" ?args list( 1 2 3 ))

; myCalc: 1 + 2 ; myCalc: 3 + 3 ; 

; => 6